UnityShader法线纹理的应用（在世界空间下计算）

2020-05-16 18:40 327人阅读评论(0)

与前文的区别就是在不同的空间下计算，效果相同，可以根据方便在不同的空间下实现

Shader "ShaderPath/WorldNMShader"//shader的选择路径
{
	Properties//该Shader可控的属性
	{
		_MainTex ("MainTex", 2D) = "white" {}//纹理贴图
		_BumpTex ("BumpTex", 2D) = "white" {}//法线纹理贴图
		_BumpScale ("BumpScale", Range(-1,1)) = 1 //凹凸程度
		_DiffuseColor ("DiffuseColor",Color) = (1,1,1,1)//漫反射的主色调
		_SpecularColor ("SpecularColor",Color) = (1,1,1,1)//高光反射的主色调
		_Gloss ("Gloss",Range(1,100)) = 2 //光泽度（反光度） 控制高光区域的大小
	}
	SubShader//子着色器
	{
		// 以下均为默认值，详情可查看以往博客
		Cull Back ZWrite On ZTest LEqual

		Pass
		{
			Tags {"LightMode"="ForwardBase"} 
			//与ENDCG相照应，将CG代码包裹
			CGPROGRAM
			//顶点函数定义
			#pragma vertex vert  
			//片元函数定义
			#pragma fragment frag
			//引入必要的Unity库 如下面的UnityObjectToClipPos 就是库中函数
			#include "UnityCG.cginc"
			//引入光照库 _LightColor0需要用
			#include "Lighting.cginc"
			struct appdata
			{
				float4 vertex : POSITION;//每个顶点结构体必须有的
				float3 normal : NORMAL;//定义法线
				float4 tangent :TANGENT;//定义切线
				float4 texcoord : TEXCOORD0;//存储第一章纹理的坐标信息
			};

			struct v2f
			{
				float4 T2W0 : TEXCOORD0;
				float4 T2W1 : TEXCOORD1;
				float4 T2W2 : TEXCOORD2;
				float4 uv : TEXCOORD3;//用于存储纹理信息
				float4 pos : SV_POSITION;//每个片元结构体必须有的
			};
			
			sampler2D _MainTex;
			sampler2D _BumpTex;
			float4 _MainTex_ST;//图片的（平铺和偏移系数）如果要使图片的Tilling和Offset生效就必须定义
			float4 _BumpTex_ST;//图片的（平铺和偏移系数）如果要使图片的Tilling和Offset生效就必须定义
			float _BumpScale;
			fixed4 _DiffuseColor;
			fixed4 _SpecularColor;
			float _Gloss;

			v2f vert (appdata v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);//把顶点从模型空间转换到剪裁空间
				o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);//使图片对应的_ST生效，这里就是_MainTex_ST
				o.uv.zw = TRANSFORM_TEX(v.texcoord, _BumpTex);//使图片对应的_ST生效，这里就是_BumpTex_ST
				float3 worldPos = mul(unity_ObjectToWorld,v.vertex);
				float3 worldNormal = UnityObjectToWorldNormal(v.normal);
				float3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
				float3 worldBiNormal = cross(worldNormal,worldTangent) * v.tangent.w;
				o.T2W0 = float4(worldTangent.x,worldBiNormal.x,worldNormal.x,worldPos.x);
				o.T2W1 = float4(worldTangent.y,worldBiNormal.y,worldNormal.y,worldPos.y);
				o.T2W2 = float4(worldTangent.z,worldBiNormal.z,worldNormal.z,worldPos.z);
				//w位用来存放世界坐标，才不会浪费空间
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target//返回一个RGBA到模型上
			{
				float3 worldPos = float3(i.T2W0.w,i.T2W1.w,i.T2W2.w);
				//要区分UnityWorldSpaceLightDir()传入一个float3的世界坐标 和 WorldSpaceLightDir()传入一个float4的模型的顶点坐标
				//UnityWorldSpaceViewDir()传入一个float3的世界坐标 WorldSpaceViewDir()传入一个float4的模型的顶点坐标
				//可以理解后面的是用在顶点着色器
				fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
				fixed4 packedNormal = tex2D(_BumpTex,i.uv.zw);//采样_BumpTex里面的法线信息
				//UnpackNormal英文含义就是 解压法线 将法线从颜色信息里面解压出来
				fixed3 tangentNormal = UnpackNormal(packedNormal);
				//切线空间的法线是单位长度为1的，所以只要求出其中两个就可以利用长度求出另一个值
				tangentNormal.xy *= _BumpScale;
				tangentNormal.z = sqrt(1-saturate(dot(tangentNormal.xy,tangentNormal.xy)));
				//将法线从切线空间转到世界空间  所有的计算都要在同一个空间计算！！！
				tangentNormal = normalize(half3(dot(tangentNormal,i.T2W0.xyz),dot(tangentNormal,i.T2W1.xyz),dot(tangentNormal,i.T2W2.xyz)));
				fixed3 albedo = tex2D(_MainTex,i.uv.xy).rgb * _DiffuseColor;//采样主贴图的纹理颜色
				//半罗伯特反射
				fixed3 diffuse = _LightColor0.rgb * albedo * (1+dot(lightDir,tangentNormal))/2;
				//Blinn-Phong模型高光 
				fixed3 halfView = normalize(lightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _SpecularColor * pow(saturate(dot(tangentNormal,halfView)),_Gloss);
				return fixed4(diffuse + specular,1);
			}
			ENDCG
		}
	}
}

效果如下：

代码中有一个地方需要小小推导一下，在把法线从法线空间下转到世界空间的时候为什么是这么用
tangentNormal = normalize(half3(dot(tangentNormal,i.T2W0.xyz),dot(tangentNormal,i.T2W1.xyz),dot(tangentNormal,i.T2W2.xyz)));
也就是，为什么矩阵
$\begin{bmatrix} T2W0.x & T2W1.x & T2W2.x\\T2W0.y & T2W1.y & T2W2.y\\T2W0.z & T2W1.z & T2W2.z \end{bmatrix}\quad\begin{bmatrix} x \\ y\\z \end{bmatrix}\quad$
是 切线空间到世界空间的变换矩阵
首先我们要确定一件事 切线空间的 x,y,z分别是切线，副切线，法线 对应代码中的worldTangent、worldBiNormal、worldNormal，模型的每个点都有各自的切线空间
Ps.在计算worldBiNormal的时候用的是 worldTangent和worldNormal叉乘，因为切线，副切线，法线是两两垂直的，最后还要 乘 v.tangent.w，是因为v.tangent.w里面存放着切线的方向（上/下）
继续回到变换矩阵的问题上：